In a follow-up comment to my answer on his AJAX question on Yahoo! Answers, mzanime2000 posed a problem faced by many ASP.NET programming beginners: how to get ASP.NET to return plain text only for use in AJAX.
Wow thanks! Pretty nice well-detailed response. Now I just hope I can get it to work with ASP.NET, I see that you used PHP in your example. One thing I still dont get though, is how Ajax invokes the SQL data when it looks like you used PHP to do the msql_connect part. And PHP is pre-processed too
ASP.NET is based around two output models: HTML and XML. The whole approach assumes you’re either going to spit out a Web page or some XML at the end of the process. Thus, all the controls, all the tutorials … everything is aimed at outputting HTML or XML. But for an AJAX data source such as the type I discussed in my previous blog entry, you need plain text.
The fix is to remove all HTML formatting from the ASPX page, and place our code directly into the ASPX page itself. That will let us call upon Response.ContentType, which will send our database results as text — which is just what our Google Maps API, and all other AJAX applications, want to see.
Step 1: The Opening Code
To begin, we need to declare the page language and import three namespaces: the regular expressions namespace, which we will use to test the querystring input; System.Data, which holds some generic data-handling items we need; and SqlClient, which handles dealing with a SQL Server database.
If you are using Access or another data store, you’d probably want to change SqlClient to Odbc or OleDb, depending on what you normally use. Fortunately, the Odbc and OleDb namespaces include connection, command and datareader objects that are fundamentally the same as those in SqlClient, so amending this script to match your database should be easy.
<%@ Import Namespace="System.Text.RegularExpressions" %> <%@ Import Namespace="System.Data" %> <%@ Import Namespace="System.Data.SqlClient" %>
Next, we need a simple Page_Load subroutine. This subroutine will check the “pid” querystring variable on our page and make sure it’s in range by running it through a regular expression.
In our case, the expression — ^[0-7]{1,1}$ — says, “The input should begin (^) with a number from 0 to 7 ([0-7]). It should have at least one character ({1,) and be no longer than one character (1}). There should be nothing after that one character ($).”
If the querystring does not match those requirements, we’ll note that the input is bad; if it does, we’ll go ahead and try to get a matching record via a function called GetRecord(), which I will describe shortly.
We then set the content type of the page to be text/plain, and echo out either the out-of-range error message or the result of GetRecord() to the client.
Sub Page_Load(Sender As Object, E As EventArgs)
Dim strOut As String
Dim reInput As New Regex("^[0-7]{1,1}$")
If Not reInput.IsMatch(Request.QueryString("pid")) Then
strOut = "<p>Input out of range.</p>"
Else
strOut = GetRecord(Request.QueryString("pid"))
End If
Response.ContentType = "text/plain"
Response.Write(strOut)
End Sub
Step 2: The GetRecord() Function
Our function begins with a simple database connection and command to get the record that matches the unique ID value we sent to it.
In this case, I’m using a text command because it’s easiest to use and because the input should be safe, given the fact that we checked it for range with a regular expression before we passed it. However, whereever possible you should use parameterized queries and stored procedures, because they are far better protected from injection, poisoning and other abuse.
Function GetRecord(intID As Integer) As String
Dim strOut As String
Dim objConn As New SqlConnection("your connection string")
Dim objCmd As New SqlCommand("SELECT * FROM mapstable WHERE record_id = " & intID, objConn)
objCmd.CommandType = CommandType.Text
The next step is to open the connection and populate a SqlDataReader with the results of the query. A SqlDataReader is a forward-only, read-only method to get rows from a query, and is perfectly suited for our needs here. (There are versions of SqlDataReader in the Odbc And OleDb data namespaces; cleverly enough, they are called OdbcDataReader and OleDbDataReader. Change this code as appropriate.)
If the SqlDataReader does not have any rows, we know there is no matching record, and we send a string that states as much as our output.
If we do have rows, we know there is a match, so we go ahead and read the record. We then construct the output we want to display to the user and assign that to the output.
Finally, we clean up our database objects and the function returns — that is, sends to the requesting code — the value of our output string.
objConn.Open()
Dim objReader As SqlDataReader = objCmd.ExecuteReader()
If Not objReader.HasRows() Then
strOut = "<p>No matching records found</p>"
Else
objReader.Read()
Dim strBody As String = objReader("item_description")
strOut = "<h1>" + objReader("item_title") + "</h1>" + vbCrLf
strOut += "<p><strong>Year constructed:</strong> " + objReader("item_year") + "</p>" + vbCrLf
strOut += strBody.Replace(vbCrLf, "<br />")
End If
objReader.Close()
objConn.Close()
objCmd.Dispose()
objConn.Dispose()
Return strOut
End Function
And that’s all there is to it. There is no working demo for this item. To use it in conjunction with the previous solution on Google Maps / DIV updating, you need to change the URL variable in the showDivInfo() function to use info.aspx, not info.php. I distribute code under the GNU GPL version 3.